大复活术脚本

西伯利亚的忠犬

模仿盟重新城的大复活术的脚本。老有人私聊我咋弄，干脆就发出来。一些细节没去做，比如复活时的进度条、放生时的确定询问之类等等，不过大致的功能都是有的。反正脚本我就丢这里了，看得懂就看，看不懂就算。


QF
[@KILLMON]

#IF
#ACT
MOV N$已复活标识 1



[@MagSelfFunc1036]
#CALL [西伯利亚的二季/大复活术.txt] @大复活术开始



QD:

[@大复活术开始]
{
#IF
#ACT
CLOSEMERCHANTBIGDLG
GOTO @_@大复活术仓库内容计算
#SAY
<这里是大复活术仓库，您当前拥有：/SCOLOR=251>< <$STR(U214)>/SCOLOR=250> <个仓库位！/SCOLOR=251>\
<TEXT:你当前杀死的怪物为：:0:110{FCOLOR=251}><TEXT:<$KILLMONNAME>　:10:110{FCOLOR=249}><TEXT:复活怪物:80:110{FCOLOR=251}/@复活怪物当宝宝> \
<$STR(S$大复活术仓库内容)>

[@_@大复活术仓库内容计算]
#IF
EQUAL T214
#ACT
MOV U214 1
MOV T214 无|无|无|无|无
MESSAGEBOX 初次使用复活术，免费赠送一个仓库位！

#IF
#ACT
MOV S$大复活术仓库内容
TEXTSPLIT | <$STR(T214)> S300
MOV N$复活术仓库循环标识 300
LOOPGOTO @_@加载大复活术仓库 <$STR(U214)>
ClearVAR S300 5

[@_@加载大复活术仓库]
#IF
#ACT
MOV S$当前收容怪物 <$STR(S<$STR(N$复活术仓库循环标识)>)>
SetStringBlank S$当前收容怪物 15 1
INC S$大复活术仓库内容 <当前仓库位收容怪物：/SCOLOR=253><　<$STR(S$当前收容怪物)>/SCOLOR=70>　<召唤/@大复活术召唤怪物(<$STR(S$当前收容怪物)>)>　　<放生/@大复活术放生怪物(<$STR(S$当前收容怪物)>,<$STR(N$复活术仓库循环标识)>)>\

#IF
#ACT
INC N$复活术仓库循环标识 1

[@大复活术召唤怪物]
#IF
EQUAL <$SCRIPTPARAM1> 无
#ACT
MESSAGEBOX 你啥都没有招个der啊！！
BREAK

#IF
#ACT
TEXTSPLIT | <$STR(T214)> S300
KILLSLAVE 1 <$STR(S300)>
KILLSLAVE 1 <$STR(S301)>
KILLSLAVE 1 <$STR(S302)>
KILLSLAVE 1 <$STR(S303)>
KILLSLAVE 1 <$STR(S304)>
RECALLMOB <$SCRIPTPARAM1>
ClearVAR S300 5

[@大复活术放生怪物]
#IF
EQUAL <$SCRIPTPARAM1> 无
#ACT
MESSAGEBOX 你啥都没有放个der啊！！
BREAK

#IF
#ACT
TEXTSPLIT | <$STR(T214)> S300
MOV S<$SCRIPTPARAM2> 无
MOV T214 <$STR(S300)>|<$STR(S301)>|<$STR(S302)>|<$STR(S303)>|<$STR(S304)>
ClearVAR S300 5
MESSAGEBOX 放生<$SCRIPTPARAM1>成功！！
GOTO @大复活术开始

[@复活怪物当宝宝]
#IF
EQUAL N$已复活标识 0
#ACT
SENDMSG 6 该怪物你已经复活过了，每杀死一次只有一次复活机会！！
BREAK

#IF
CHECKTEXTLIST ..\QuestDiary\西伯利亚的二季\不可复活怪物列表.txt <$KILLMONNAME>
#ACT
SENDMSG 6 当前怪物不允许被复活！
BREAK

#IF
#ACT
MOV N$复活怪物循环标识 300
MOV N$仓库是否存在空位标识 0
TEXTSPLIT | <$STR(T214)> S300
LOOPGOTO @_@复活时判断仓库位置 <$STR(U214)>

#IF
EQUAL N$仓库是否存在空位标识 0
#ACT
SENDMSG 6 你的仓库已经没有空位了，请先放生！
BREAK

#IF
#ACT
GetDBMonsterFieldValue <$KILLMONNAME> HP N$当前复活怪物血量
DIV N$当前复活怪物血量 1000

#IF
#ACT
MOV N$已复活标识 0

#IF
RANDOMEX 1 <$STR(N$当前复活怪物血量)>
#ACT
MOV N$复活怪物循环标识 300
LOOPGOTO @_@复活成功存仓 <$STR(U214)>
MESSAGEBOX 复活成功！，已将怪物<$KILLMONNAME>保存至仓库！
GOTO @大复活术开始
#ELSEACT
MESSAGEBOX 复活失败，<$STR(N$当前复活怪物血量)>分之1几率未达成！！！

#IF
#ACT
ClearVAR S300 5

[@_@复活成功存仓]
#IF
EQUAL S<$STR(N$复活怪物循环标识)> 无
#ACT
MOV S<$STR(N$复活怪物循环标识)> <$KILLMONNAME>
MOV T214 <$STR(S300)>|<$STR(S301)>|<$STR(S302)>|<$STR(S303)>|<$STR(S304)>
ENDLOOP

#IF
#ACT
INC N$复活怪物循环标识 1

[@_@复活时判断仓库位置]
#IF
EQUAL S<$STR(N$复活怪物循环标识)> 无
#ACT
MOV N$仓库是否存在空位标识 1

#IF
#ACT
INC N$复活怪物循环标识 1
}

idc58588

狗哥威武，一统江湖！

sazp1314

我竟然看懂了一内内。。太佩服我自己了

laoliumang

狗神威武

woailiufu

狗神威武

传奇千秋

厉害啊

heng521

传奇客家

大复活术是干嘛用的？

zzg52130

这个厉害！！！！！！！！

一一

狗哥牛逼，6666